home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / umich / falcon / programm.ing / nt_dsp1.lzh / NT_DSP1.MSA / FLOAT / FPDIV.ASM < prev    next >
Assembly Source File  |  1989-01-24  |  4KB  |  102 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAIMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; Last Update 5 Oct 87   Version 2.0
  7. ;
  8. fpdiv   ident   2,0
  9. ;
  10. ; MOTOROLA DSP56000/1 FPLIB VERSION 2
  11. ;
  12. ; FPDIV - FLOATING POINT DIVIDE SUBROUTINE
  13. ;
  14. ; Entry points: fdiv_xa R = A / X
  15. ;               fdiv_xy R = Y / X
  16. ;
  17. ;       m = 24 bit mantissa (two's complement, normalized fraction)
  18. ;
  19. ;       e = 14 bit exponent (unsigned integer, biased by +8191)
  20. ;
  21. ; Input variables:
  22. ;
  23. ;   X   x1 = ma  (normalized)
  24. ;       x0 = ea
  25. ;
  26. ;   Y   y1 = my  (normalized)
  27. ;       y0 = ey
  28. ;
  29. ;   A   a2 = sign extension of ma
  30. ;       a1 = ma  (normalized)
  31. ;       a0 = zero
  32. ;
  33. ;       b2 = sign extension of ea (always zero)
  34. ;       b1 = ea
  35. ;       b0 = zero
  36. ;
  37. ; Output variables:
  38. ;
  39. ;   R   a2 = sign extension of mr
  40. ;       a1 = mr  (normalized)
  41. ;       a0 = zero
  42. ;
  43. ;       b2 = sign extension of er (always zero)
  44. ;       b1 = er
  45. ;       b0 = zero
  46. ;
  47. ; Error conditions:     Set CCR L=1 if divide by zero error.  Result is
  48. ;                       set to the maximum floating point value having
  49. ;                       the same sign as the dividend if the dividend
  50. ;                       is non-zero.  Result is set to floating point
  51. ;                       zero if the dividend is zero.  The CCR L bit
  52. ;                       remains set until cleared by the user.
  53. ;
  54. ;                       Set CCR L=1 if floating point overflow.  Result
  55. ;                       is set to the maximum floating point value of the
  56. ;                       correct sign.  The CCR L bit remains set until
  57. ;                       cleared by the user.
  58. ;
  59. ;                       Set CCR L=1 if floating point underflow.  Result
  60. ;                       is set to floating point zero.  The CCR L bit
  61. ;                       remains set until cleared by the user.
  62. ;
  63. ; Assumes n0, m0, shift constant table and scaling modes
  64. ; initialized by previous call to the subroutine "fpinit".
  65. ;
  66. ; Alters Data ALU Registers
  67. ;       a2      a1      a0      a
  68. ;       b2      b1      b0      b
  69. ;       y1                      x0
  70. ;
  71. ; Alters Address Registers
  72. ;       r0
  73. ;
  74. ; Alters Program Control Registers
  75. ;       pc      sr               
  76. ;
  77. ; Uses 0 locations on System Stack
  78. ;
  79. ;
  80. fdiv_xy tfr     y0,b    y1,a            ;get ey, my
  81. fdiv_xa sub     x0,b    fp_space:fp_ebias,x0 ;calculate er' = ea - ex,get ebias
  82.         add     x0,b                    ;add ebias to er'
  83.         tfr     x1,b    b,r0            ;get mx, save er'
  84.         tst     b                       ;check for divisor mx = 0
  85.         jne     _div1                   ;jump if divisor not zero
  86.         tst     a                       ;check for dividend ma = 0
  87.         jne     limit                   ;jump if dividend not zero
  88.         or      #$40,ccr                ;set L=1 for divide by zero error
  89. _div1   asr     a       a,b             ;force fractional quotient, copy ma
  90.         jeq     done                    ;jump if dividend ma = 0 (underflow)
  91.         abs     a       (r0)+           ;make dividend positive, adjust er'
  92.         eor     x1,b                    ;calculate quotient sign
  93.         and     #$fe,ccr                ;clear carry (quotient sign bit)
  94.         rep     #24                     ;repeat for 24 bit quotient
  95.         div     x1,a                    ;generate one quotient bit
  96.         jpl     _qpos                   ;jump if positive quotient
  97.         neg     a                       ;negate mr' for negative quotient
  98. _qpos   move    a0,a                    ;get quotient mr'
  99.         tst     a                       ;normalize mr' 1 extra bit
  100.         norm    r0,a                    ;shift 1 bit and update exponent by 1
  101.         jmp     norm1                   ;normalize and check for errors
  102.